public class ArrayWrapper {
  private var array: [Int]

  public func copyElement(from: Int, to: Int) {
    array[to] = array[from]
  }

  init(array: [Int]) { self.array = array }
}

  // load the array property and retain it
  %6 = ref_element_addr %2 : $ArrayWrapper, #ArrayWrapper.array
  %7 = begin_access [read] [dynamic] %6 : $*Array<Int>
  %8 = load %7 : $*Array<Int>
  retain_value %8 : $Array<Int>
  end_access %7 : $*Array<Int>

  // load the from element, no problem here
  %11 = alloc_stack $Int
  // function_ref Array.subscript.getter
  %12 = function_ref @$sSayxSicig : $@convention(method) <τ_0_0> (Int, @guaranteed Array<τ_0_0>) -> @out τ_0_0
  %13 = apply %12<Int>(%11, %0, %8) : $@convention(method) <τ_0_0> (Int, @guaranteed Array<τ_0_0>) -> @out τ_0_0
  %14 = load %11 : $*Int

  // modify access while the array is still retained forces a copy
  %15 = ref_element_addr %2 : $ArrayWrapper, #ArrayWrapper.array
  %16 = begin_access [modify] [dynamic] %15 : $*Array<Int>
  // function_ref Array.subscript.modify
  %17 = function_ref @$sSayxSiciM : $@yield_once @convention(method) <τ_0_0> (Int, @inout Array<τ_0_0>) -> @yields @inout τ_0_0
  (%18, %19) = begin_apply %17<Int>(%1, %16) : $@yield_once @convention(method) <τ_0_0> (Int, @inout Array<τ_0_0>) -> @yields @inout τ_0_0
  store %14 to %18 : $*Int
  end_apply %19
  end_access %16 : $*Array<Int>

  // Why wasn't the array released before the modify? This array value
  // is only used in the right side of the assignment!
  release_value %8 : $Array<Int>